【VBA】ノード名を指定せずにXMLをパースする

<?xml version="1.0" encoding="UTF-8" ?>
<fruits>
  <item>
    <name>みかん</name>
    <color>オレンジ</color>
    <value>10</value>
  </item>
  <item>
    <name>ぶどう</name>
    <color>紫</color>
    <value>20</value>
  </item>
</fruits>

    'XMLをロードする
    Set XMLDoc = CreateObject("MSXML2.DOMDocument.6.0")
    XMLDoc.Load ("C:\test.xml")

Private sh As Object
Private row As Long
Private col As Integer

Public Sub main()
    Dim path As String
    Dim XMLDoc As Object
    
    'ファイル選択ダイアログでパスを指定
    path = getFilePath(ThisWorkbook.path)
    If path = "" Then Exit Sub
    
    'XMLをロードする
    Set XMLDoc = CreateObject("MSXML2.DOMDocument.6.0")
    XMLDoc.Load (path)
    If (XMLDoc.parseError.ErrorCode <> 0) Then
        'ロード失敗時
        MsgBox XMLDoc.parseError.reason, vbCritical
        GoTo endProc
    End If
    
    '出力シートを定義
    Set sh = ThisWorkbook.Worksheets("Sheet1") 'Sheet1に出力
    sh.Cells.Clear
    row = 1
    col = 1
    
    '子ノードを書き出す
    Call getchildren(XMLDoc)
    
'後処理（開放）
endProc:
    Set sh = Nothing
    Set XMLDoc = Nothing

End Sub

'ファイル選択ダイアログでパスを指定
Private Function getFilePath(default As String)
    Dim path As Variant
    
    ChDir default
    path = Application.GetOpenFilename("XMLファイル(*.xml),*.xml")

    If VarType(path) = vbBoolean Then
        getFilePath = ""
    Else
        getFilePath = path
    End If
End Function

'子ノードを書き出す
Private Sub getchildren(XMLParent As Variant)
    If Not XMLParent Is Nothing Then
        For Each XMLChilld In XMLParent.ChildNodes
            If XMLChilld.ChildNodes.Length = 0 Then
                If Not XMLParent.BaseName = "" Then
                    sh.Cells(row, col).Value = XMLParent.BaseName
                    col = col + 1
                    sh.Cells(row, col).Value = XMLChilld.Text
                End If
            Else
                Call getchildren(XMLChilld)
            End If
        Next
        If col <> 1 Then
            row = row + 1
            col = 1
        End If
    End If
End Sub